HTMLのテキスト部分を順次選択するマクロ

ダウンロード

line_content.zip

更新履歴

Version 1.20 (2025/2/28)

マクロ名の変更

サブルーチンの修正

探索を左方向と右方向で分けた

不要な処理の削除

ソースコードの整理

ソースコード

setcompatiblemode 0x20200;
#x = x; #y = y;
#cont = 0;
disabledraw;

if (selecting) {
	escape;
	call CheckTagTop;	//連続実行時の処理
	#cont = ##return;
	if (code == 13) moveto2 0, lineno + 1;
	else if (code == -1) {
		beep;
		goto End;
	}
}

if (column && (!#cont)) call SeekLeft;
call SeekRight;

while (code == 13 && #ct == #ce) {	//論理行末の処理
	moveto2 0, lineno + 1;
	call SeekRight;
}

if (#ct == #ce) {	//対象がなければ警告音で終了
	moveto #x, #y;
	beep;
	goto End;
}

moveto2 #ct, lineno;
beginsel;
moveto2 #ce, lineno;
endsel;

goto End;

SeekLeft:	//左方向にタグを探索
	while (column) {
		left;
		call CheckTagTop;
		if (##return) break;
		call CheckTagEnd;
		if (##return) {
			right;
			break;
		}
	}
	return;

SeekRight:	//右方向に行の内容及びタグの間を探索
	if (!column) while (code == 9 || code == 32) right;	//論理行頭のタブ、半角スペースを無視
	while (1) {	//連続するタグを無視
		call CheckTagTop;
		if (!##return) break;
		$$str = gettext2(column, lineno, column + 4, lineno);
		if (!strstr($$str, "<!--")) searchdown "-->";
		else if (!strstr($$str, "<?")) searchdown "?>";
		else searchdown "[^ <=>?-]>", regular;
		if (result) moveto selendx, selendy;
		else break;
	}
	#ct = column;
	
	while (code != 13 && code != -1) {
		call CheckTagTop;
		if (##return) break;
		call CheckTagEnd;
		if (##return) #ct = column + 1;
		right;
	}
	#ce = column;
	
	return;

CheckTagTop:	//カーソル位置がタグの先頭かを調べる
	##r = 0;
	if (code == '<') {
		right;
		if ((code >= 'a' && code <= 'z') || (code >= 'A' && code <= 'Z')
		 || code == '!' || code == '/' || code == '?') ##r = 1;
		left;
	}
	return ##r;

CheckTagEnd:	//カーソル位置がタグの末尾かを調べる
	##r = 0;
	if (column && code == '>') {
		left;
		if (!(code == 32 || code == '-'
		 || code == '<' || code == '=' || code == '>')) ##r = 1;
		else if (column && code == '-') {
			left;
			if (code == '-') ##r = 1;
			right;
		}
		right;
	}
	return ##r;

End:	//終了処理
	enabledraw;
	endmacro;

colorcodeを使えばもっと簡単に書けますし、最初はそうしていたんですが、「ファイルタイプ別の設定」に依存するので、汎用性を持たせるために全体を書き直しました。
これにより、HTML以外のファイルでも使いやすくなっています。

ただし、あくまでもHTMLを優先しているので、HTMLタグのような記述があると、行選択するつもりが部分選択になってしまう場合があります。
一応、演算子のような記述は検出しないようにしてあります。